DEFINE STATUSBAR

Creates a StatusBar Control

Standard Syntax (xBase Style):

 DEFINE STATUSBAR
    [ OF | PARENT <ParentWindowName> ]
    [ FONT <cFontName> SIZE <nFontSize> ]
    [ TOP ]
    STATUSITEM <cItemCaption>
       [ WIDTH <nWidth>]
       [ ACTION <ActionProvedureName> | <bBlock> ]
       [ ICON <cIconName>]
       [ FLAT | RAISED ]
       [ TOOLTIP <cToolTipText>]
   [ DATE
      [ WIDTH <nWidth> ]
      [ ACTION <ActionProvedureName> | <bBlock> ]
      [ TOOLTIP <cToolTipText>] ]
   [ CLOCK
      [ WIDTH <nWidth> ]
      [ ACTION <ActionProvedureName> | <bBlock> ]
      [ TOOLTIP <cToolTipText> ]
      [ INTERVAL <nIntervalUpdate> ] ]
   [ KEYBOARD
      [ WIDTH <nWidth> ]
      [ ACTION <ActionProvedureName> | <bBlock> ]
      [ TOOLTIP <cToolTipText> ]
      [ INTERVAL <nIntervalUpdate> ] ]
    ...
    ...
END STATUSBAR

Alternate Syntax:

DEFINE STATUSBAR
   [ PARENT <ParentWindowName> ]
   [ FONTNAME <cFontName> FONTSIZE <nFontSize> ]
   [ TOP <lValue> ]
   STATUSITEM <cItemCaption>
      [ WIDTH <nWidth>]
      [ ACTION <ActionProvedureName> | <bBlock> ]
      [ ICON <cIconName>]
      [ STYLE FLAT | RAISED ]
      [ TOOLTIP <cToolTipText>]
  [ DATE
      [ WIDTH <nWidth> ]
      [ ACTION <ActionProvedureName> | <bBlock> ]
      [ TOOLTIP <cToolTipText>] ]
  [ CLOCK
      [ WIDTH <nWidth> ]
      [ ACTION <ActionProvedureName> | <bBlock> ]
      [ TOOLTIP <cToolTipText> ]
      [ INTERVAL <nIntervalUpdate> ] ]
  [ KEYBOARD
      [ WIDTH <nWidth> ]
      [ ACTION <ActionProvedureName> | <bBlock> ]
      [ TOOLTIP <cToolTipText> ]
      [ INTERVAL <nIntervalUpdate> ] ]
  ...
   ...
END STATUSBAR

StatusBar Properties:

• Parent (D)
• FontName (D)
• FontSize (D)
• Top (D)

StatusItem Properties:

• Item (nItemIndex)
• Width (D)
• Icon (D)
• Style (D)
• ToolTip (D)

StatusItem Events:

• Action (D)

Hints:

• The tooltip for a part will only be displayed if the part has an icon and no text or if all of the text cannot be displayed inside the part.

• Since that can be only one StatusBar control per window, there is no need to give it a name (the name €˜StatusBar€™ is automatically assigned).

Sample:

#include "hmg.ch"
Function Main
   DEFINE WINDOW Form_1 ;
      AT 0,0 ;
      WIDTH 600 HEIGHT 400 ;
      TITLE 'HMG StatusBar Demo' ;
      MAIN
      DEFINE MAIN MENU
         POPUP '&StatusBar Test'
            ITEM 'Set StatusBar Item 1' ACTION Form_1.StatusBar.Item(1) := "New value 1"
            ITEM 'Set StatusBar Item 3' ACTION Form_1.StatusBar.Item(3) := "New value 3"
            ITEM 'Set StatusBar Item Icon' ACTION Form_1.StatusBar.Icon (3) := 'New.iCO'
            ITEM 'Open Other Window...' ACTION Modal_Click()
         END POPUP
         POPUP '&Help'
            ITEM '&About' ACTION MsgInfo ("HMG StatusBar Demo")
         END POPUP
      END MENU
      DEFINE STATUSBAR
         STATUSITEM "Item 1" ACTION MsgInfo('Click! 1')
         STATUSITEM "Item 2" WIDTH 100 ACTION MsgInfo('Click! 2')
         STATUSITEM 'A Car!' WIDTH 100 ICON 'Car.Ico'
         CLOCK
         DATE
      END STATUSBAR
   END WINDOW
   CENTER WINDOW Form_1
   ACTIVATE WINDOW Form_1
Return Nil

STATUSBAR Control improvement

<ParentWindowName>.StatusBar.IconHandle (nItem) := hIcon