WeekNumbers Property

Specifies whether week numbers are shown for MonthCalendar control

Syntax:

WeekNumbers <lValue>

Sample:

#include "hmg.ch"
Function Main
   DEFINE WINDOW Form_1 ;
      AT 0,0 ;
      WIDTH 640 HEIGHT 480 ;
      TITLE "Month Calendar Control Demo" ;
      MAIN
      @ 210,10 MONTHCALENDAR Month_2 ;
         VALUE CTOD("01/01/2001") ;
         FONT "Courier" SIZE 12 ;
         TOOLTIP "Month Calendar Control WeekNumbers" ;
         WEEKNUMBERS
   END WINDOW
   ACTIVATE WINDOW Form_1
Return Nil

When Property

Codeblock array (one element per column) that is evaluated prior to field editing for Browse control

Syntax:

When <abValues>

Sample:

@ 10,10 BROWSE Browse_1 ;
 WIDTH 610 ;
 HEIGHT 390 ;
 HEADERS { 'Code' , 'First Name' , 'Last Name' } ;
 WIDTHS { 150 , 150 , 150 } ;
 WORKAREA Test ;
 FIELDS { 'Test->Code' , 'Test->First' , 'Test->Last' } ;
 VALUE 0 ;
 EDIT ;
 WHEN { { || Test->Code == 10 } , , { || Test->Married == .t. } }

WholeDropDown Property

Specifies whether a Toolbar button will be used to open a dropdown menu

Syntax:

WholeDropDown <lValue>

Sample:

DEFINE TOOLBAR ToolBar_a BUTTONSIZE 30,30 FONT 'Arial' SIZE 8 FLAT
   BUTTON Button_1a ;
      CAPTION '&Undo' ;
      PICTURE 'button4.bmp' ;
      ACTION MsgInfo('Undo')
   BUTTON Button_2a ;
      CAPTION '&Save' ;
      PICTURE 'button5.bmp' ;
      WHOLEDROPDOWN
      DEFINE DROPDOWN MENU BUTTON Button_2a
         ITEM 'Exit' ACTION MsgInfo('Exit')
         ITEM 'About' ACTION MsgInfo ("HMG ToolBar Demo")
      END MENU
END TOOLBAR

Width Property

Set \/ Gets width of a gui object

Syntax:

Width <nValue> (Control Definition)
<ParentWindowName>.<ControlName>.Width := nWidth
<ParentWindowName>.<ControlName>.Width --> nWidth

Widths Property

Specifies column widths for Browse and Grid controls. It must be specified as a numeric array containing one element for each column in the control

Syntax:

Widths <anValues>

Sample:

@ 10,10 GRID Grid_1 ;
   WIDTH 620 ;
   HEIGHT 330 ;
   HEADERS {'Column 1','Column 2','Column 3'} ;
   WIDTHS {140,140,140} ;
   ITEMS { {‘1’,’2’,’3’} , {‘4’,’5’,’6’} }

WindowType Property

Set The Window Type

Syntax:

WindowType Main | Child | Modal | SplitChild | Standard | Panel

WorkArea Property

Specifies the workarea for a Browse control

Syntax:

WorkArea <xcValue>

Sample:

DEFINE BROWSE Browse_1
   COL 10
   ROW 10
   WIDTH 610
   HEIGHT 390
   HEADERS { 'Code' , 'First Name' , 'Last Name' }
   WIDTHS { 150 , 150 , 150 }
   WORKAREA Test
   FIELDS { 'Test->Code' , 'Test->First' , 'Test->Last' }
   VALUE 1
END BROWSE

Wrap Property

Specifies whether Spinner control content can be wrapped

Syntax:

Wrap <lValue>

Sample:

#include "hmg.ch"
Function Main
   DEFINE WINDOW Form_Main ;
      AT 0,0 ;
      WIDTH 640 HEIGHT 480 ;
      TITLE "Main Window" ;
      MAIN
      @ 150,250 SPINNER Spinner_2 ;
         RANGE 0,100 ;
         VALUE 5 ;
         WIDTH 100 ;
         WRAP
   END WINDOW
   CENTER WINDOW Form_Main
   ACTIVATE WINDOW Form_Main
Return Nil