Icon Property

Specifies an icon for a StatusBar item or a Window

Syntax:

Icon <cValue>

Image Property

Specifies a character array containing image filenames or reourcenames to be used with Browse, ComboBox, Grid and Tree controls (a character string for MenuItems)

Syntax:

Image <acValues>

For MenuItems, it must be specified as a character string containing the image filename or resourcename

ImageSize, ImageWidth, ImageHeight Property

Specifies image width for toolbar buttons

Syntax:

ImageSize nWidth, nHeight

Alternative Syntax:

ImageWidth <nWidth>

ImageHeight <nHeight>

Sample:

DEFINE TOOLBAR ToolBar_b BUTTONSIZE 40,40 IMAEGESIZE 29, 20 FONT 'ARIAL' SIZE 8 FLAT
 BUTTON Button_1b ;
 CAPTION 'More ToolBars...' ;
 PICTURE 'button7.bmp' ;
 ACTION MsgInfo('Click! 2');
 BUTTON Button_2b ;
 CAPTION 'Button 2' ;
 PICTURE 'button7.bmp' ;
 ACTION MsgInfo('Click! 2');
 SEPARATOR
 BUTTON Button_3b ;
 CAPTION 'Button 3' ;
 PICTURE 'button7.bmp' ;
 ACTION MsgInfo('Click! 3')
 END TOOLBAR

Increment Property

Specifies numeric increment (when the user clicks up and down arrows) in a Spinner control

Syntax:

Increment <nValue>

Sample:

#include "hmg.ch"
Function Main
 DEFINE WINDOW Form_Main ;
 AT 0,0 ;
 WIDTH 640 HEIGHT 480 ;
 TITLE "Main Window" ;
 MAIN
 @ 150,250 SPINNER Spinner_2 ;
 RANGE 0,100 ;
 VALUE 5 ;
 WIDTH 100 ;
 TOOLTIP "Range 0,100 WRAP READONLY INCREMENT 5" ;
 WRAP INCREMENT 5
 END WINDOW
 ACTIVATE WINDOW Form_Main
Return Nil

InputItems Property

Allows to control data input in the Browse control

Syntax:

InputItems <aaValues>

This property is an array (one element for each browse column). Each element (if specified) must be a two dimensional array. The first column in the array must contain the data to be shown to the user. The second column must contain the data to be stored in the table (ID) for each text row in the array.

InputMask Property

Specifies the edit mask for a TextBox control

Syntax:

InputMask <cValue>

InputMask String (Numeric Textbox):

9 Displays digits

$ Displays a dollar sign in place of a leading space

* Displays an asterisk in place of a leading space

. Specifies a decimal point position

, Specifies a comma position

InputMask String (Non-Numeric Textbox):

9 Digits

A Alphabetic Characters

! Converts an alphabetic character to uppercase

(All other characters ar included in text in the position indicated by

the mask)

Interval Property

Specifies interval in milliseconds for timer control

Syntax:

Interval <nValue>

Item Property

Set \/ Get item text in a listbox, combobox, grid and Statusbar controls

Syntax:

 <WindowName>.<ControlName>. Item (<nItem>) := ItemText
 <WindowName>.<ControlName> . Item (<nItem>) --> ItemText

<ItemText> type is character for lists and combos, and array for grids

(in this case, the array length, is equal to column count)

Items Property

Set items for a ComboBox at control definition

Sy ntax:

Items <acValue> (Control Definition)

ItemCount Property

Get item count in a listbox, combobox or grid

Syntax:

ItemCount <nValue>

<WindowName>.<ControlName>. ItemCount --> nItemCount

ItemImages Property

Specifies Item Images For a Tree Item

Syntax:

ItemImages <acValues>

A character array (one or two elements) containing image filenames or resourcenames for tree items when unselected (first array item) and selected (optional second array item).

Sample:

DEFINE TREE Tree_1 AT 10,10 WIDTH 200 HEIGHT 400 VALUE 3;
NODEIMAGES { "doc_fl.bmp" };
ITEMIMAGES { "cl_fl.bmp", "op_fl.bmp" };
NOROOTBUTTON
    NODE 'Root' IMAGES {'world'}
       TREEITEM 'Item 1.1'
       TREEITEM 'Item 1.2'
       TREEITEM 'Item 1.3'
       NODE 'Docs'
          TREEITEM 'Docs 1' IMAGES {'varios'}
       END NODE
       NODE 'Notes' IMAGES {'varios'}
          TREEITEM 'Notes 1'
          TREEITEM 'Notes 2'
          TREEITEM 'Notes 3'
          TREEITEM 'Notes 4'
          TREEITEM 'Notes 5'
       END NODE
       NODE 'Books' IMAGES {'book'}
          TREEITEM 'Book 1' IMAGES {'doc'}
          TREEITEM 'Book 2' IMAGES {'doc'}
          NODE 'Book 3'IMAGES {'book'}
            TREEITEM 'Book 3.1'
            TREEITEM 'Book 3.2'
         END NODE
      END NODE
    END NODE
END TREE

ItemSource Property

Links a ComboBox control to a table field

Syntax:

ItemSource <xcValue>

When ITEMSOURCE property is set to a fieldname, ‘Value' property uses the physical record number, as in browse.

If you set the VALUESOURCE property to a fieldname, its containt is returned instead the physical record number.

Sample:

#Include "hmg.ch"
Function Main()
DEFINE WINDOW Form_1 ;
   AT 0,0 ;
   WIDTH 365 ;
   HEIGHT 120 ;
   TITLE "Exemplos ComboBox New" ;
   MAIN ;
   ON INIT OpenTables() ;
   ON RELEASE CloseTables()
   DEFINE MAIN MENU
      DEFINE POPUP '&Test'
        MENUITEM 'Get Value' ACTION MsgInfo( Str ( Form_1.Combo_1.Value ) )
        MENUITEM 'Set Value' ACTION Form_1.Combo_1.Value := 2
        MENUITEM 'Refresh' ACTION Form_1.Combo_1.Refresh
        MENUITEM 'DisplayValue' ACTION MsgInfo ( Form_1.Combo_1.DisplayValue )
      END POPUP
   END MENU
   @010,010 COMBOBOX Combo_1 ;
      ITEMSOURCE CIDADES->DESCRICAO ;
      VALUE 5 ;
      WIDTH 200 HEIGHT 100 ;
      FONT "Arial" SIZE 9 ;
      TOOLTIP "Combo Cidades"
END WINDOW
ACTIVATE WINDOW Form_1
Return

Procedure Opentables()
   Use Cidades Alias Cidades New
   Index On Descricao To Cidades1
Return

Procedure CloseTables()
   Use
Return